99BASIC / DarkBASIC 総合スレッド

**まちがって名前消しちゃいました。** · 2014/08/14(木) 04:01:07.41

マイコン少年からWindows世代までどうぞ

・ 99BASIC（http://www.sagami.ne.jp/tadaka/99Basic/）
　MSXやPC-8801世代の旧式マイクロソフトBASICに準拠したBASIC。
　DirectXはサポートしておらず、簡単な2Dインターフェイスのみ使える。
　インタープリター形式で直接実行モードもある。

・ DarkBASIC（http://darkbasic.thegamecreators.com/）
　VisualBASIC以前の旧式マイクロソフトBASICの進化形。
　DirectXをサポート、商用アプリ作成可能。
　C言語にはない強力な文字列操作、複雑な記述が可能。

**まちがって名前消しちゃいました。** · 2014/08/24(日) 02:10:52.60

10 ' SAVE"BALL6.BAS",A 'QQBAS ﾎﾞｰﾙ反射･3次元風味(笑)･Zﾊﾞｯﾌｧ･ﾌｫｸﾞ･半透明
20 CLEAR SYSTEM:CLEAR 110,384,192,4:PALETTE CLEAR:DEFSNG A-Z
30 SIZX=80:SIZY=24
40 WIDTH SIZX,SIZY:SCREEN 3,5:CLS 3
50 DIM PT%(23,((48+1)*(48+1))\4)
60 DIM PT1%(23,((48+1)*(48+1))\4)
70 DIM PT2%(23,((48+1)*(48+1))\4)
80 DIM PT3%(23,((48+1)*(48+1))\4)
90 '
100 ' F - FOG / TTTTTTT - TONE
110 ' 76543210
120 ' FTTTTTTT PALETTE CONTAINER SET
130 '
140 FOG_G=60:FOG_R=40:FOG_B=80
150 '
160 FOR F=0 TO 1
170 FOR TT=0 TO 127
180 CL=(F*128)+TT
190 IF TT>0 THEN 230 'SKIP
200 JG=0:JR=0:JB=0
210 GOTO 250 'SKIP2
220 'SKIP
230 JG=(TT*2)+1:JR=(TT*2)+1:JB=(TT*2)+1
240 'SKIP2
250 IF F=0 THEN 280 'SKIP
260 JG=(JG+FOG_G*2)/3:JR=(JR+FOG_R*2)/3:JB=(JB+FOG_B*2)/3
270 'SKIP
280 PALETTE CL,(JG,JR,JB)
290 NEXT TT
300 NEXT F
310 '
320 PALETTE 0,(FOG_G,FOG_R,FOG_B)
330 '
340 FOR K=0 TO 23:CLS 2
350 FOR J=K TO 23
360 CL=INT((J-K)*5.52)
370 CIRCLE( 24,24),24-J,CL :PAINT( 24,24),CL ,CL
380 CIRCLE( 72,24),24-J,CL+128:PAINT( 72,24),CL+128,CL+128
390 CIRCLE(120,24),24-J,CL :PAINT(120,24),CL ,CL
400 CIRCLE(168,24),24-J,CL+128:PAINT(168,24),CL+128,CL+128
410 '
420 CT=0
430 FOR L=0 TO 47
440 FOR M=96+CT TO 191 STEP 2
450 PSET(M,L),0
460 NEXT M
470 CT=(CT+1) AND 1
480 NEXT L
490 '
500 NEXT J

**まちがって名前消しちゃいました。** · 2014/08/24(日) 02:11:14.15

510 GET @3,( 0,0)-STEP(47,47), PT%(K,0)
520 GET @3,( 48,0)-STEP(47,47),PT1%(K,0) 'FOG
530 GET @3,( 96,0)-STEP(47,47),PT2%(K,0) 'HALF
540 GET @3,(144,0)-STEP(47,47),PT3%(K,0) 'FOG+HALF
550 NEXT K
560 '
570 FOG=12.5
580 N=128
590 DIM X(N-1),Y(N-1),Z(N-1),SX(N-1),SY(N-1),SZ(N-1),HF(N-1)
600 FOR J=0 TO N-1
610 X(J)=RND(SIZX*8):Y(J)=RND(SIZY*16):Z(J)=RND(23+1)
620 SX(J)=(RND*1.5)+0.25:SY(J)=(RND*1.5)+0.25:SZ(J)=(RND/10)+0.1
630 HF(J)=RND(1+1)
640 NEXT J
650 '
660 INTERVAL ON,(1000\60):ON INTERVAL GOSUB 1100
670 '
680 IF TSYNC=0 THEN 680
690 TSYNC=0
700 LINE(0,0)-(SIZX*8-1,SIZY*16-1),0,BF 'CLS 3
710 FOR J=0 TO N-1
720 X(J)=X(J)+SX(J):Y(J)=Y(J)+SY(J):Z(J)=Z(J)+SZ(J)
730 IF X(J)< 0 THEN X(J)= 0:SX(J)= ABS(SX(J))
740 IF X(J)> (SIZX*8)-48 THEN X(J)= (SIZX*8)-48:SX(J)=-ABS(SX(J))
750 IF Y(J)< 0 THEN Y(J)= 0:SY(J)= ABS(SY(J))
760 IF Y(J)>(SIZY*16)-48 THEN Y(J)=(SIZY*16)-48:SY(J)=-ABS(SY(J))
770 IF Z(J)< 1 THEN Z(J)= 1:SZ(J)= ABS(SZ(J))
780 IF Z(J)> 23 THEN Z(J)= 23:SZ(J)=-ABS(SZ(J))
790 NEXT J
800 '
810 ZF=0
820 FOR J=0 TO (N-1)-1
830 IF Z(J)=>Z(J+1) THEN 890 'SKIP
840 SWAP X(J), X(J+1):SWAP Y(J), Y(J+1):SWAP Z(J), Z(J+1)
850 SWAP SX(J),SX(J+1):SWAP SY(J),SY(J+1):SWAP SZ(J),SZ(J+1)
860 SWAP HF(J),HF(J+1)
870 ZF=1
880 'SKIP
890 NEXT J
900 IF ZF=1 THEN 810
910 '
920 FOR J=0 TO N-1
930 JX=X(J)/(((Z(J)/23)+1))+(27.8*Z(J))/4
940 JY=Y(J)/(((Z(J)/23)+1))+(17.3*Z(J))/4
950 IF Z(J)>FOG THEN 1010 'SKIP
960 IF HF(J)=1 THEN 990 'SKIP11
970 PUT@(JX,JY),PT%(Z(J),0):GOTO 1050 'SKIP2
980 'SKIP11
990 PUT@(JX,JY),PT2%(Z(J),0):GOTO 1050 'SKIP2
1000 'SKIP

**まちがって名前消しちゃいました。** · 2014/08/24(日) 02:12:04.00

1010 IF HF(J)=1 THEN 1040 'SKIP22
1020 PUT@(JX,JY),PT1%(Z(J),0):GOTO 1050 'SKIP2
1030 'SKIP22
1040 PUT@(JX,JY),PT3%(Z(J),0)
1050 'SKIP2
1060 NEXT J
1070 SCREEN
1080 GOTO 680
1090 '
1100 INTERVAL OFF:TSYNC=1:INTERVAL ON:RETURN